// ---------------------------------------------
// Drogar ToB Interjections
// ---------------------------------------------
BEGIN LK#DR25J

// Advice on Godhood
INTERJECT_COPY_TRANS FINSOL01 27 LK#Drogar_FinSol
  == LK#DR25J ~The power of a god...well, it might be worth thinkin' about.  But when this is done we'll be goin' our separate ways anyway, so do what ye want.~
END


// Post Decision Comment
EXTEND_BOTTOM FINSOL01 29
  IF ~InParty("Drogar") Global("LK#DrogarPCGod","GLOBAL",0)~ THEN DO ~SetGlobal("LK#DrogarPCGod","GLOBAL",1)~ EXTERN LK#DR25J LK#DrogarPCGod
END

EXTEND_BOTTOM FINSOL01 30
  IF ~InParty("Drogar") Global("LK#DrogarPCGod","GLOBAL",0)~ THEN DO ~SetGlobal("LK#DrogarPCGod","GLOBAL",1)~ EXTERN LK#DR25J LK#DrogarPCGod
END

EXTEND_BOTTOM FINSOL01 31
  IF ~InParty("Drogar") Global("LK#DrogarPCGod","GLOBAL",0)~ THEN DO ~SetGlobal("LK#DrogarPCGod","GLOBAL",1)~ EXTERN LK#DR25J LK#DrogarPCGod
END

EXTEND_BOTTOM FINSOL01 32
  IF ~InParty("Drogar") Global("LK#DrogarPCNotGod","GLOBAL",0)~ THEN DO ~SetGlobal("LK#DrogarPCNotGod","GLOBAL",1)~ EXTERN LK#DR25J LK#DrogarPCNotGod
END

APPEND LK#DR25J
  IF ~~ LK#DrogarPCGod
    SAY ~Good choice.  When yer up there, take a moment to remember the aid I gave you.  Lady Luck can always use a little nudgin' now and then.~
    COPY_TRANS FINSOL01 31
  END

  IF ~~ LK#DrogarPCNotGod
    SAY ~Yer decision.  Pity, though.~
    COPY_TRANS FINSOL01 32
  END
END


// Volo
EXTEND_TOP SARVOLO 9 #5
  + ~InParty("Drogar")~ + ~Tell me about Drogar.~ + LK#Drogar_Volo_0
END

APPEND SARVOLO
IF ~~ LK#Drogar_Volo_0
    SAY ~A quiet dwarven cleric of Vergadain, Drogar Delgyth's adventures with <CHARNAME> have made him famous throughout even his homeland, the Dales.  Not much is known about him beyond his love of dice and coin, but those who know him speak of a fiercesome fighter with a love for good ale..~
    IF ~~ EXTERN LK#DR25J LK#Drogar_Volo_1
  END
  
  IF ~~ LK#Drogar_Volo_2
    SAY ~I shall make the corrections post-haste, master dwarf.  However, I'll have you know you are extremely lucky to even get a mention in <CHARNAME>'s biography, so I would keep your opinions on me to yourself.~
    IF ~~ EXTERN SARVOLO 9
  END
END


APPEND LK#DR25J
  IF ~~ LK#Drogar_Volo_1
    SAY ~Those who know me?  A love of good ale?  Where are ye gettin' this from, ye thick-skulled idiot?  Fer one, ye *don't* know me, and fer two, ye'll find I haven't had a tanker of ale in over a century.  If ye're going to write about me, at least get the facts straight.~
    IF ~~ EXTERN SARVOLO LK#Drogar_Volo_2
  END
END

