// ---------------------------------------------
// Nephele P Dialogue
// ---------------------------------------------
BEGIN LK#NE25P

// Kicked Out
IF ~Global("LK#NepheleJoined","LOCALS",1)~ LK#Nephele_KO
  SAY ~Obviously it's your decision, but I'd prefer to continue travelling with you.~
  ++ ~Fair enough. Stay with me.~ DO ~SetGlobal("LK#NepheleJoined","LOCALS",1) JoinParty()~ EXIT
  + ~AreaCheck("AR4500")~ + ~Just wait here for a while, if you would.~ DO ~SetGlobal("LK#NepheleJoined","LOCALS",0) MoveToPointNoInterrupt([1585.1374]) Face(0)~ EXIT
  + ~!AreaCheck("AR4500") !AreaCheck("AR4000") !AreaCheck("AR6200")~ + ~I'll send you back to the pocket plane and come by for you there.~ DO ~SetGlobal("LK#NepheleJoined","LOCALS",0) CreateVisualEffectObject("SPDIMNDR",Myself) Wait(2) MoveBetweenAreas("AR4500",[1585.1374],0)~ EXIT
  + ~!AreaCheck("AR4500") !AreaCheck("AR4000") !AreaCheck("AR6200")~ + ~Wait here, if you would.~ DO ~SetGlobal("LK#NepheleJoined","LOCALS",0)~ + LK#Nephele_KO_1
END

IF ~~ LK#Nephele_KO_1
  SAY ~All right, but I don't want to be waiting too long. Come by soon, all right?~
  IF ~~ EXIT
END

// Rejoining
IF ~Global("LK#NepheleJoined","LOCALS",0)~ LK#Nephele_Rejoin
  SAY ~It's good to see you! Do you wish to travel together again?~
  ++ ~Yes, that's a good idea.~ + LK#Nephele_Rejoin1
  ++ ~No, stay here a while longer.~ + LK#Nephele_KO_1
END

IF ~~ THEN BEGIN LK#Nephele_Rejoin1
  SAY ~Excellent! Let's get going.~
  IF ~~ THEN DO ~SetGlobal("LK#NepheleJoined","LOCALS",1) JoinParty()~ EXIT
END
