// ---------------------------------------------
// Nephele Out of Party dialogue
// ---------------------------------------------
BEGIN LK#DROG

// Joining Dialogue
IF ~NumTimesTalkedTo(0) Global("LK#NephIntro","AR2010",0)~ LK#NJ_0
  SAY ~Haven't you ever seen a halfling before, dear? Don't gawk. It's a tragic sight on a famous adventurer like yourself.~
  = ~Nephele Samios, but you can call me Nephele. And you are <CHARNAME>, hero of Trademeet!~
  ++ ~Pleased to make your acquaintance.~ DO ~SetGlobal("LK#NephIntro","AR2010",1)~ + LK#NJ_1
  + ~Gender(Player1,MALE)~ + ~What do you want?~ DO ~SetGlobal("LK#NephIntro","AR2010",1)~ + LK#NJ_2_0
  + ~Gender(Player1,FEMALE)~ + ~What do you want?~ DO ~SetGlobal("LK#NephIntro","AR2010",1)~ + LK#NJ_2_1
  ++ ~First thing's first; don't call me "dear."~ DO ~SetGlobal("LK#NephIntro","AR2010",1)~ + LK#NJ_3
END

IF ~~ LK#NJ_1
  SAY ~And I yours.~
  IF ~~ GOTO LK#NJ_4
END

IF ~~ LK#NJ_2_0
  SAY ~Why, to come with you, of course! Isn't that what all the ladies want with you? (chuckle)~
  ++ ~What *are* you talking about?~ + LK#NJ_5
  ++ ~You? Coming with me? You've got to be joking.~ + LK#NJ_6
  ++ ~I've no time for you, old woman. Leave me alone.~ + LK#NJ_7
  ++ ~What skills do you have?~ + LK#NJ_8
  ++ ~What makes you think I'd want you to come with me?~ + LK#NJ_9
END

IF ~~ LK#NJ_2_1
  SAY ~To come with you, of course! Why else would I be speaking to you, girl?~
  ++ ~Don't call me "girl!" I'm a grown woman, and I don't appreciate being spoken to like I'm an eight year old.~ + LK#NJ_10
  ++ ~What makes you think I'd want you to come with me?~ + LK#NJ_9
  ++ ~What *are* you talking about?~ + LK#NJ_5
  ++ ~You? Coming with me? You've got to be joking.~ + LK#NJ_6
  ++ ~I've no time for you, old woman. Leave me alone.~ + LK#NJ_7
  ++ ~What skills do you have?~ + LK#NJ_8
END
  
IF ~~ LK#NJ_3
  SAY ~I'm afraid you'll just have to put up with that one - it's a habit too ingrained to be rid of!~
  IF ~~ GOTO LK#NJ_4
END

IF ~~ LK#NJ_4
  SAY ~My, my, you really are everything you're cracked up to be--word on the street is that you fought off the rabid animals attacking Trademeet singlehandedly, and then delivered the town from those tight-fisted genies! Of course, I'm fairly sure you had help.~
  = ~Well, dearie, I suppose we had better get going, hmm?~
  ++ ~Wait, what? What're you talking about?~ + LK#NJ_5
  ++ ~You? Coming with me? You've got to be joking.~ + LK#NJ_6
  ++ ~I've no time for you, old woman. Leave me alone.~ + LK#NJ_7
  ++ ~What makes you think I'd want you to come with me?~ + LK#NJ_9
END

IF ~~ LK#NJ_5
  SAY ~I thought I'd made that quite plain, my dear. I'm joining you in your quest. I'm a very capable illusionist, and it's about time I used these old bones of mine to do some good.~
  ++ ~I... suppose you could come with me, if you'd like? I have to warn you, though, I'm trying to defeat an evil mage and save my foster sister from his clutches. This is no average quest. Death is a high likelihood.~ + LK#NJ_11
  ++ ~Are you certain? Adventuring is dangerous work. You might get hurt.~ + LK#NJ_11
  ++ ~I'm sorry, but I'm not interested. I've got enough help.~ + LK#NJ_12
  ++ ~I'd like to know a little more about you, first.~ + LK#NJ_13
END

IF ~~ LK#NJ_6
  SAY ~Joking? While I may enjoy the occasional giggle, dear, this is no joke. I'm a very capable illusionist, and it's about time I used these old bones of mine to do some good.~
  ++ ~I... suppose you could come with me, if you'd like? I have to warn you, though, I'm trying to defeat an evil mage and save my foster sister from his clutches. This is no average quest. Death is a high likelihood.~ + LK#NJ_11
  ++ ~Are you certain? Adventuring is dangerous work. You might get hurt.~ + LK#NJ_11
  ++ ~I'm sorry, but I'm not interested. I've got enough help.~ + LK#NJ_12
  ++ ~I'd like to know a little more about you, first.~ + LK#NJ_13
END

IF ~~ LK#NJ_7
  SAY ~How rude! Didn't your mother teach you manners, young <PRO_MANWOMAN>? No matter. I will be here if you are ever in need of an illusionist.~
  IF ~~ EXIT
END

IF ~~ LK#NJ_8
  SAY ~I was an adventurer in my youth - travelled quite a ways, and became quite the illusionist. I'm a little rusty, but these old bones still have  bit of spark left in them. It'll do me good to get out and do something once more. I've had quite enough of the home life for my liking, I think.~
  ++ ~I... suppose you could come with me, if you'd like? I have to warn you, though, I'm trying to defeat an evil mage and save my foster sister from his clutches. This is no average quest. Death is a high likelihood.~ + LK#NJ_11
  ++ ~Are you certain? Adventuring is dangerous work. You might get hurt.~ + LK#NJ_11
  ++ ~I'm sorry, but I'm not interested. I've got enough help.~ + LK#NJ_12
  ++ ~I'd like to know a little more about you, first.~ + LK#NJ_13
END

IF ~~ LK#NJ_9
  SAY ~I was an adventurer in my youth - travelled quite a ways, and became quite the illusionist. I'm a little rusty, but these old bones still have  bit of spark left in them. It'll do me good to get out and do something once more. I've had quite enough of the home life for my liking, I think.~
  ++ ~I... suppose you could come with me, if you'd like? I have to warn you, though, I'm trying to defeat an evil mage and save my foster sister from his clutches. This is no average quest. Death is a high likelihood.~ + LK#NJ_11
  ++ ~Are you certain? Adventuring is dangerous work. You might get hurt.~ + LK#NJ_11
  ++ ~I'm sorry, but I'm not interested. I've got enough help.~ + LK#NJ_12
  ++ ~I'd like to know a little more about you, first.~ + LK#NJ_13
END

IF ~~ LK#NJ_10
  SAY ~Compared to me, dear - and I don't mean this offensively, but - you're rather young. I've been in this world much, much longer than you have, I'd wager.~
  IF ~~ GOTO LK#NJ_9
END

IF ~~ LK#NJ_11
  SAY ~Anyone who has birthed seven children can take care of themselves when adventuring, dear. Trust me on that one.~
  IF ~~ GOTO LK#NJ_14
END

IF ~~ LK#NJ_12
  SAY ~Well, I will be here if you are ever in need of an illusionist. Goodbye!~
  IF ~~ EXIT
END

IF ~~ LK#NJ_13
  SAY ~Me? Well, there's not much to tell, really... Mother of seven, widow, an adventurer at heart. Always looking for the grass on the other side.~
  IF ~~ GOTO LK#NJ_14
END

IF ~~ LK#NJ_14
  SAY ~Well? Are we going, or would you like to stay here the night? It's a lovely place, if a bit rustic.~
  ++ ~"We" aren't going anywhere. I'm sorry, but I'm not interested.~ + LK#NJ_12
  ++ ~Why not? Come on, then. Let me introduce you to the others.~ + LK#NJ_15
  ++ ~I suppose you can come along. But if I find you're not worth the trouble, I will ask you to leave.~ + LK#NJ_16
END

IF ~~ LK#NJ_15
  SAY ~That would be lovely.~
  IF ~~ DO ~SetGlobal("LK#NepheleJoined","GLOBAL",1) JoinParty()~ EXIT
END

IF ~~ LK#NJ_16
  SAY ~Of course! Completely understandable, my dear. Now, are you going to introduce me to your companions, or shall I?~
  IF ~~ DO ~SetGlobal("LK#NepheleJoined","GLOBAL",1) JoinParty()~ EXIT
END