//Arktohl dialogue
BEGIN LK#AVA

IF ~Global("LK#ARQuest","GLOBAL",0)~
THEN BEGIN FirstMeeting
SAY ~(Before you stands an aged man, a serious expression in his golden eyes. You recognise him as the Avatar of the god Amaunator, who you recently saved from the Hate Incarnate. He inclines his head slightly, his eyes never leaving yours, and motions for you to come closer.)~
= 
~<CHARNAME>, I bear unsettling news, for both you and indeed, for all of Faerun. I am breaking many rules in speaking to you, but I feel it is imperative that you know the truths I am about to impart to you.~

IF ~~ THEN REPLY ~Nice to see you again, old chap! Hope everything is going well in, er, your equivalent of heaven and all.~ GOTO PC1.1
IF ~~ THEN REPLY ~Mighty Amaunator, I will listen to your wise words. Please continue.~ GOTO PC1.2
IF ~~ THEN REPLY ~I haven't the time for this, old man. Move from my path, lest I move you from it.~ GOTO PC1.1
END

IF ~~ THEN BEGIN PC1.1
SAY ~(The old man smiles slightly.) You have much to learn, young <CHARNAME>. For now, you must listen to what I have to say... each moment I delay could cause even greater penalties than those I will face for simply speaking to you.~ IF ~~ THEN GOTO PC1.2
END

IF ~~ THEN BEGIN PC1.2
SAY ~There has been a disturbance in the material of this plane and that of another, <CHARNAME>- a ripple, if you will. It began soon after the Shade Lord encroached upon my temple, and it ended immediately after you destroyed him. Ever since, something has not been right... I ask you to journey to the Temple and discover what occured.~
=
~I cannot say more, but it is of vital importance that you go. It is a thread which stretches back far before the time when you were born, to a time when even the land was not fully shaped, and Netheril was high in the sky.~
=
~I must leave, lest I draw undue attention...~

IF ~~ THEN REPLY ~Wait! I have a question; how is it that you are dead, and yet you speak to me?~ GOTO PC1.2.1
IF ~~ THEN REPLY ~(Remain silent.)~ GOTO PC1.2.2
IF ~~ THEN REPLY ~I will travel as soon as I can, but I'm not making any promises.~ GOTO PC1.2.2
IF ~~ THEN REPLY ~I haven't the time, Divinity. I have more important things to deal with!~ GOTO PC1.2.3
END

IF ~~  BEGIN PC1.2.1
SAY ~As long as there are those who believe, <CHARNAME>, I cannot truly die. I am a mere shade of my former self, as has been demonstrated in the past- it is an effort to, as you say, speak to you. Taking physical form is harder than one might believe at first, but it is imperative that you go to the Temple and discover what has occured.~ IF ~~ THEN GOTO PC1.2.2
END

IF ~~  BEGIN PC1.2.2
SAY ~I wish you luck, <CHARNAME> - I hope you will realise the importance of this and leave for the Umar Hills soon.~
IF ~~  DO ~SetGlobal("LK#ARQuest","GLOBAL",1) EscapeArea()~ EXIT
END

IF ~~  BEGIN PC1.2.3
SAY ~As important as a tear in the strands of existance itself? I think not. I do not have the time to persuade you, <CHARNAME>, and I will not expend the effort to. I ask you to go, and I cannot do much more.~ IF ~~ THEN GOTO PC1.2.2
END