12 replies to this topic

[Elys]

WARNING: Due to the way this program works by hooking dynamically various parts of the game executable in memory, it will be most probably detected as a suspicious file by your Antivirus software. You may have to exclude it from detection in your Antivirus options.

HyperOverride allows the user to optionally and dynamically setup (through game shortcut modification) an additional Override folder.
The content of this additional folder will have priority over the content inside the standard Override folder in case of file conflict.
I initially created this little tool so I could use an EasyTutu installation to play Baldur's Gate II campaign by "hyperOverriding" few files just by starting EasyTutu with a different shortcut. But I guess it can be used for other goals.

HyperOverride has been made and tested for "Baldur's Gate II: Throne of Bhall US patch 26498", but it should works as well for any Baldur's Gate I or II original or modded versions, and maybe for IceWind Dale too. Obviously -tabtoggle will be useless in Baldur's Gate I, since there is no highlight functionality in this last game.


Install:
-------

- Copy HOLoad.exe, HyperOverride.dll and the HyperOverride folder into your Baldur's Gate II folder (alongside BGMain.exe).

Use:
----

Just launch HOLoad.exe with the following optional parameters:

Load your custom additional override folder. The name needed by the following parameter is just the name of the folder you created inside the HyperOverride folder.
-ho:<folder name>

Turns the (Highlight) TAB key into a toggle.
-tabtoggle

Specify a different executable filename than 'BGMain.exe':
-exe:<filename>

Examples:
---------

HOLoad.exe -ho:Example_MaxAbiRoll -tabtoggle

HOLoad.exe -exe:BGMain2.exe -ho:MyBG1Files

Attached Files

•  HyperOverride_v0.0.0.1.zip   296.08K   449 downloads

Edited by Elys, 17 April 2011 - 06:29 PM.

[Azazello]

I'm kinda of surprised the lack of discussion on this tool. I guess the biggest issue--for the casual player--is 'why would I use this'?

Since most players, especially those using a mega-install, are being encouraged to biff their override folder, there might be even less need for your tool.

HOWEVER... I have a scenario perhaps you can consider: can you create a HyperCache modification?

Specifically, I'ld like to offload my cache folder to another drive, in order to save space on my main (game) drive, and even to 'junk' this offline cache folder (that is, simply delete it) in case I need to clear the cache due to some gameplaying problem.

(We could go even one step further: how's about a HyperData modif?)


btw I re-read your post several times, I still have no idea what 'Tab Toggle' is supposed to do different from the vanilla game.

[10th]

btw I re-read your post several times, I still have no idea what 'Tab Toggle' is supposed to do different from the vanilla game.

Vanilla game:
You hold TAB, and containers, loot piles etc. are highlighted while you hold TAB. As soon as you no longer hold TAB, nothing is highlighted anymore.

HyperOverride Tool:
You press TAB once, and containers, loot etc. are always highlighted. Pressing TAB a second time disables this.

10th

Edited by 10th, 19 January 2012 - 11:39 AM.

[Ascension64]

Hmm, no source? I can't check compatibility with TobEx, and things are going to get messy with multiple dlls being injected...

[Jarno Mikkola]

Hmm, no source?

That's a shame, but let's hope with little time Elys will add that too.

Since most players, especially those using a mega-install, are being encouraged to biff their override folder, there might be even less need for your tool.

Well, what if someone could add in a HyperData add on to this... See we could use the same game for Tutu, BGT, Classic Adventures and Icewind Dale in BGII under the same game folder... now that's a megamoded game if anything. Hmm, WeiDU.exe might need a tiny adjustment to work with that, but a dreamer can always dream.

[aqrit]

without looking
One has to assume that Elys is hooking the IAT for CreateFile() and PeekMessage()

and possible anything else that would boil down to a call to NtOpenFile or NtCreateFile so ( GetFileAttributes, FindFileFirst, SearchPath, etc.)

when I wrote a hack to do this I just hooked the IAT of kernel32 for ntdll calls...

Edited by aqrit, 20 January 2012 - 04:02 PM.

[Sam.]

Since most players, especially those using a mega-install, are being encouraged to biff their override folder, there might be even less need for your tool.

Well, what if someone could add in a HyperData add on to this... See we could use the same game for Tutu, BGT, Classic Adventures and Icewind Dale in BGII under the same game folder... now that's a megamoded game if anything. Hmm, WeiDU.exe might need a tiny adjustment to work with that, but a dreamer can always dream.

Keeping all the .KEY files strait would be crazy . Their already is a hierarchy of override folders, in case you didn't know...

[Azazello]

Glad to see more discussion on this...

Jarno, I remember from quite some time ago asking somewhere, maybe on PPG, about getting biggDU to redirect folders to different disks/volumes, but I think this was too bigg (haha, get it?) a request for the humble exe.

Nowadays, it's certainly more a consideration for TobEx, Taimon's or something similar like this contrib by Elys.

[Elys]

Wah. This topic is back from the dead one year after

Yes I've done it using IAT hooks on FindFirstFileA, FindNextFileA, FindClose, CreateFileA and GetAsyncKeyState(for the toggle).
Nothing is modified inside the original game code besides these few IAT entries.

Anyway for those interested, here the code. (Delphi/Pascal with Unicode)


This is the code for HOLoader:

Spoiler

program HOLoad;

{$R *.res}

uses
  Windows, SysUtils;

var
  SI: StartupInfo;
  PI: Process_Information;
  DllName: String = 'HyperOverride.dll';
  ExeName: String = 'BGMain.exe';
  HOName: String = '';
  Cmd: String = '';

procedure Error(Msg: String);
begin
  MessageBox(0, Pchar(Msg), 'HyperOverride Error', MB_ICONERROR);
end;

function FileNotExists(FileName: String): Boolean;
begin
  Result := not FileExists(FileName);
  if Result then
	Error('File: ' + FileName + ' not found!')
end;

function DirNotExists(DirName: String): Boolean;
begin
  if DirName = '' then
	begin
	  Result := False;
	  Exit;
	end;
  Result := not DirectoryExists(DirName);
  if Result then
	Error('Directory: ' + DirName + ' not found!')
end;

function Launch: Boolean;
begin
  Result := False;
  if FileNotExists(ExeName) then
	exit;
  if FileNotExists(DllName) then
	exit;
  if DirNotExists(HOName) then
	Exit;
  Result := True;
end;

procedure InjectDLL;
var
  Thread, ThreadId: dword;
  Parameters: pointer;
  t: Cardinal;
begin
  t := (length(DllName) + 1) * 2;
  Parameters := VirtualAllocEx(PI.hprocess, nil, t, MEM_COMMIT, PAGE_READWRITE);
  WriteProcessMemory(PI.hprocess, Parameters, Pchar(DllName), t, t);
  Thread := CreateRemoteThread(PI.hprocess, nil, 0, GetProcAddress(GetModuleHandle('KERNEL32.DLL'), 'LoadLibraryW'), Parameters, 0, ThreadId);
  WaitForSingleObject(Thread, INFINITE);
  VirtualFreeEx(PI.hprocess, Parameters, 0, MEM_RELEASE);
  CloseHandle(Thread);
end;

procedure InitCmd;
var
  i: Integer;
  s: String;
begin
  for i := 1 to ParamCount do
	begin
	  s := ParamStr(i);
	  if Copy(s, 1, 4) = '-ho:' then
		begin
		  HOName := 'HyperOverride\' + Copy(s, 5, length(s));
		  Cmd := Cmd + ' ' + s;
		end
	  else if AnsiLowerCase(Copy(s, 1, 5)) = '-exe:' then
		ExeName := Copy(s, 6, length(s))
	  else
		Cmd := Cmd + ' ' + s;
	end;
  Cmd := '"' + GetCurrentDir + '\' + ExeName + '"' + Cmd;
end;

begin
  InitCmd;
  if Launch then
	if CreateProcess(Pchar(ExeName), Pchar(Cmd), nil, nil, False, CREATE_SUSPENDED, nil, nil, SI, PI) then
	  begin
		InjectDLL;
		ResumeThread(PI.hThread);
		CloseHandle(PI.hprocess);
		CloseHandle(PI.hThread);
	  end
	else
	  begin
		CloseHandle(PI.hprocess);
		CloseHandle(PI.hThread);
		Error('Cannot launch "' + ExeName + '"!');
	  end;

end.

This is the code for HyperOverdrive.dll:

Spoiler

library HyperOverride;

{$R *.res}

uses
  SysUtils,
  StrUtils,
  Classes,
  Windows,
  pelib in 'pelib.pas';

type
  TSearch = record
	Handle: THANDLE;
	Index: Integer;
	Datas: Array of _WIN32_FIND_DATAA;
  end;

  PSearch = ^TSearch;

var
  HOName: String;
  TabState: Boolean = False;
  s: String;
  i: Integer;
  Searches: TList = nil;
  CodePage: Word;
  Cmd: String;

function WideStrToAnsiStr(const ws: WideString): AnsiString;
var
  l: Integer;
begin
  if ws = '' then
	Result := ''
  else
	begin
	  l := WideCharToMultiByte(CodePage, WC_COMPOSITECHECK or WC_DISCARDNS or WC_SEPCHARS or WC_DEFAULTCHAR, PWideChar(ws), -1, nil, 0, nil, nil);
	  SetLength(Result, l - 1);
	  if l > 1 then
		WideCharToMultiByte(CodePage, WC_COMPOSITECHECK or WC_DISCARDNS or WC_SEPCHARS or WC_DEFAULTCHAR, PWideChar(ws), -1, PAnsiCHar(Result), l - 1, nil, nil);
	end;
end;

function AnsiStrToWideStr(const s: AnsiString): WideString;
var
  l: Integer;
begin
  if s = '' then
	Result := ''
  else
	begin
	  l := MultiByteToWideChar(CodePage, MB_PRECOMPOSED, PAnsiCHar(s), -1, nil, 0);
	  SetLength(Result, l - 1);
	  if l > 1 then
		MultiByteToWideChar(CodePage, MB_PRECOMPOSED, PAnsiCHar(s), -1, PWideChar(Result), l - 1);
	end;
end;

function MyFindFirstFileA(lpFileName: PAnsiCHar; var lpFindFileData: _WIN32_FIND_DATAA): THANDLE; stdcall;
var
  FileName: AnsiString;
  FindFileData: _WIN32_FIND_DATAA;
  Handle: THANDLE;
  HOHandle: THANDLE;
  Search: PSearch;
  NotFound: Boolean;
  i: Integer;
begin
  if AnsiCompareText(ExtractFileDir(AnsiStrToWideStr(lpFileName)), GetCurrentDir + '\override') = 0 then
	begin
	  Search := nil;
	  Handle := FindFirstFileA(lpFileName, FindFileData);
	  Result := Handle;
	  if Handle <> INVALID_HANDLE_VALUE then
		begin
		  if Searches = nil then
			Searches := TList.Create;
		  New(Search);
		  Searches.Add(Search);
		  Search.Handle := Handle;
		  repeat
			SetLength(Search.Datas, Length(Search.Datas) + 1);
			Move(FindFileData, Search.Datas[Length(Search.Datas) - 1], SizeOf(_WIN32_FIND_DATAA));
		  until not FindNextFileA(Handle, FindFileData);
		end;

	  FileName := WideStrToAnsiStr(HOName + ExtractFileName(AnsiStrToWideStr(lpFileName)));
	  HOHandle := FindFirstFileA(PAnsiCHar(FileName), FindFileData);
	  if HOHandle <> INVALID_HANDLE_VALUE then
		begin
		  Result := HOHandle;
		  if Handle <> INVALID_HANDLE_VALUE then
			FindClose(Handle)
		  else
			begin
			  if Searches = nil then
				Searches := TList.Create;
			  New(Search);
			  Searches.Add(Search);
			end;
		  Search.Handle := HOHandle;
		  repeat
			NotFound := True;
			for i := 0 to Length(Search.Datas) - 1 do
			  if AnsiCompareText(AnsiStrToWideStr(Search.Datas[i].cFileName), AnsiStrToWideStr(FindFileData.cFileName)) = 0 then
				begin
				  Move(FindFileData, Search.Datas[i], SizeOf(_WIN32_FIND_DATAA));
				  NotFound := False;
				  break;
				end;

			if NotFound then
			  begin
				SetLength(Search.Datas, Length(Search.Datas) + 1);
				Move(FindFileData, Search.Datas[Length(Search.Datas) - 1], SizeOf(_WIN32_FIND_DATAA));
			  end;
		  until not FindNextFileA(HOHandle, FindFileData);
		end;
	  if Search <> nil then
		begin
		  Search.Index := 1;
		  Move(Search.Datas[0], lpFindFileData, SizeOf(_WIN32_FIND_DATAA));
		end;
	end
  else
	Result := FindFirstFileA(lpFileName, lpFindFileData);
end;

function MyFindNextFileA(hFindFile: THANDLE; var lpFindFileData: _WIN32_FIND_DATAA): Longbool; stdcall;
var
  i: Integer;
  Search: PSearch;
begin
  if Searches <> nil then
	for i := 0 to Searches.Count - 1 do
	  begin
		Search := PSearch(Searches[i]);
		if Search.Handle = hFindFile then
		  begin
			Result := Length(Search.Datas) >= Search.Index + 1;
			if Result then
			  begin
				Move(Search.Datas[Search.Index], lpFindFileData, SizeOf(_WIN32_FIND_DATAA));
				Inc(Search.Index);
			  end;
			Exit;
		  end;
	  end;

  Result := FindNextFileA(hFindFile, lpFindFileData);
end;

function MyFindClose(hFindFile: THANDLE): Longbool; stdcall;
var
  i: Integer;
  Search: PSearch;
begin
  if Searches <> nil then
	for i := 0 to Searches.Count - 1 do
	  begin
		Search := PSearch(Searches[i]);
		if Search.Handle = hFindFile then
		  begin
			Dispose(Search);
			Searches.Delete(i);
			if Searches.Count = 0 then
			  begin
				Searches.Free;
				Searches := nil;
			  end;
			break;
		  end;
	  end;

  Result := FindClose(hFindFile);
end;

function MyCreateFileA(lpFileName: PAnsiCHar; dwDesiredAccess: Longword; dwShareMode: Longword; lpSecurityAttributes: Pointer; dwCreationDisposition: Longword; dwFlagsAndAttributes: Longword; hTemplateFile: THANDLE): THANDLE; stdcall;
var
  FileName: AnsiString;
begin
  if AnsiCompareText(ExtractFileDir(AnsiStrToWideStr(lpFileName)), GetCurrentDir + '\override') = 0 then
	begin
	  FileName := WideStrToAnsiStr(HOName + ExtractFileName(AnsiStrToWideStr(lpFileName)));
	  if FileExists(AnsiStrToWideStr(FileName)) then
		begin
		  Result := CreateFileA(PAnsiCHar(FileName), dwDesiredAccess, dwShareMode, lpSecurityAttributes, dwCreationDisposition, dwFlagsAndAttributes, hTemplateFile);
		  Exit;
		end;
	end;
  Result := CreateFileA(lpFileName, dwDesiredAccess, dwShareMode, lpSecurityAttributes, dwCreationDisposition, dwFlagsAndAttributes, hTemplateFile);
end;

function MyGetAsyncKeyState(const vKey: Longint): Smallint; stdcall;
begin
  Result := GetAsyncKeyState(vKey);
  if vKey <> 9 then
	Exit;
  if Result and 1 = 1 then
	TabState := not TabState;
  if TabState then
	Result := -32768
  else
	Result := 0;
end;

function HookIAT(ModuleName: PCHar; FunctionName: PCHar; NewAddress: Pointer): Boolean;
var
  hd: HModule;
  dosHeader: PIMAGE_DOS_HEADER;
  ntHeader: PIMAGE_NT_HEADERS;
  ImportDesc: PIMAGE_IMPORT_DESCRIPTOR;
  pThunk: PIMAGE_THUNK_DATA;
  OriginalFunction: DWORD;
  OldFlag: DWORD;

begin
  Result := False;
  hd := GetModuleHandle(nil);
  OriginalFunction := DWORD(GetProcAddress(GetModuleHandle(ModuleName), FunctionName));
  if OriginalFunction = 0 then
	Exit;
  dosHeader := PIMAGE_DOS_HEADER(hd);
  if dosHeader.e_magic = IMAGE_DOS_SIGNATURE then
	begin
	  ntHeader := PIMAGE_NT_HEADERS(DWORD(dosHeader) + DWORD(dosHeader.e_lfanew));
	  if ntHeader.Signature <> IMAGE_NT_SIGNATURE then
		Exit
	  else
		begin
		  ImportDesc := PIMAGE_IMPORT_DESCRIPTOR(DWORD(dosHeader) + ntHeader.OptionalHeader.DataDirectory[IMAGE_DIRECTORY_ENTRY_IMPORT].VirtualAddress);
		  if ImportDesc = PIMAGE_IMPORT_DESCRIPTOR(ntHeader) then
			Exit
		  else
			while ImportDesc.Name <> 0 do
			  begin
				if AnsiCompareText(AnsiStrToWideStr(PAnsiCHar(DWORD(dosHeader) + ImportDesc.Name)), ModuleName) = 0 then
				  break;
				Inc(DWORD(ImportDesc), SizeOf(IMAGE_IMAGE_IMPORT_DESCRIPTOR));
			  end;
		  pThunk := PIMAGE_THUNK_DATA(DWORD(dosHeader) + ImportDesc.FirstThunk);
		  while pThunk._Function <> 0 do
			begin
			  if (pThunk._Function = OriginalFunction) and VirtualProtect(@pThunk._Function, 4, PAGE_READWRITE, @OldFlag) then
				begin
				  pThunk._Function := DWORD(NewAddress);
				  VirtualProtect(@pThunk._Function, 4, OldFlag, @OldFlag);
				  Result := True;
				end;
			  Inc(DWORD(pThunk), SizeOf(IMAGE_THUNK_DATA));
			end;
		end;
	end;
end;

procedure Abort;
begin
  MessageBox(0,'HyperOverride has failed to modify the memory of the game. You should immediately quit the game after you close this message!','HyperOverride Error', MB_ICONERROR);
end;

begin
  Cmd := AnsiLowerCase(CmdLine);
  for i := 1 to ParamCount do
	begin
	  s := LowerCase(ParamStr(i));
	  if s = '-tabtoggle' then
		begin
		  if not HookIAT('user32.dll', 'GetAsyncKeyState', @MyGetAsyncKeyState) then
			Abort;
		end
	  else if Copy(s, 1, 4) = '-ho:' then
		if HookIAT('kernel32.dll', 'FindFirstFileA', @MyFindFirstFileA) and HookIAT('kernel32.dll', 'FindNextFileA', @MyFindNextFileA) and HookIAT('kernel32.dll', 'FindClose', @MyFindClose) and HookIAT('kernel32.dll', 'CreateFileA', @MyCreateFileA) then
		  begin
			HOName := 'HyperOverride\' + Copy(s, 5, Length(s)) + '\';
			CodePage := GetACP;
		  end
		else
		  Abort;
	end;

end.

Edited by Elys, 29 February 2012 - 10:09 PM.

[Azazello]

Welcome back, and thanks for the contribution.

Are you willing to try at HyperCache / HyperData? I'm willing to help with the beta-testing (should have my game discs in a week or 2).

Edited by Azazello, 01 March 2012 - 06:40 AM.

[Elys]

For HyperCache it seems you are just interested into moving the Cache folder somewhere else. It's a different problem and one that only requires to change the Cache path used by the game. There is no "overriding" aspect of files.

If you are on Windows Vista/7, you can just create a directory junction by deleting the cache folder and typing the following line at command prompt (while having administrator privileges):

mklink /j "C:\Program Files\Baldur's Gate\data\cache" "D:\SomewhereElse\cache"

(Obviously replacing the paths with the one matching your configuration)

It's also possible to do the same on Windows 2000/XP, but it's a little more complicated.

About "HyperData", I'm not sure of what you want. The Override folder is by itself already sort of an extension of the Data folder.
So if you just want to be able to launch the game while choosing a different Data folder according to the shortcut used, you could just let the Data folder empty (or filled with files common to all your different "Data setup", and use various HyperOverride folders as Data folders.

Note: HyperOverride was not optimized for such "HyperData" use, although it would work it might eventually make loading time slighly slower on slow hardward configuration.

Edited by Elys, 01 March 2012 - 08:20 AM.

[Azazello]

For HyperCache it seems you are just interested into moving the Cache folder somewhere else. It's a different problem and one that only requires to change the Cache path used by the game. There is no "overriding" aspect of files.

If you are on Windows Vista/7, you can just create a directory junction by deleting the cache folder and typing the following line at command prompt (while having administrator privileges):

mklink /j "C:\Program Files\Baldur's Gate\data\cache" "D:\SomewhereElse\cache"

Directory junctions--interesting solution. I'll investigate this. Thanks.

btw This command needs to run every time the game is started, yes? So that means a batch file or other wrapper that includes the game EXE, for example BALDUR.BAT:

mklink /j "C:\Program Files\Baldur's Gate\data\cache" "D:\SomewhereElse\cache"
"C:\Program Files\Baldur's Gate\bgMain.exe"

About "HyperData", I'm not sure of what you want. The Override folder is by itself already sort of an extension of the Data folder.
So if you just want to be able to launch the game while choosing a different Data folder according to the shortcut used, you could just let the Data folder empty (or filled with files common to all your different "Data setup", and use various HyperOverride folders as Data folders.

Note: HyperOverride was not optimized for such "HyperData" use, although it would work it might eventually make loading time slighly slower on slow hardward configuration.

I think I see where the confusion is coming up: you originally created HyperOverride to override the default folder. My proposal is not to replace anything--I'ld like offload \override, \data maybe others from the game directory disk/volume to elsewhere. So are junctions the way-to-go to do this?

Offloading large data collections is of course going to increase load-times. It's a balance that the player has to decide for him/herself.


For the benefit of our viewing audience, why would someone want to do this--an example... you've installed the game to a laptop with limited storage, and you can't or don't want to put in another internal harddrive, then \data, \override, etc. could be placed on an external harddrive, usb pen, maybe even a remote drive (to a "cloud" drive perhaps?).


btw Elys, does your tool accept UNC paths?

Edited by Azazello, 03 March 2012 - 04:36 AM.

[Elys]

No, the mklink commands create a permanent Directory Junction.

Once created if you browse in your Baldur's Gate folder, you will see Cache directory. It works the same way that a normal directory. Excepted anything done inside is in fact done to the real folder you chose as target with mklink.
(PS: The target folder must exist before using mklink)

To delete a Directory Junction, just delete the "fake" directory using the rmdir command.
You can also use the Windows Explorer to delete the "fake" directory, but then unlike with the rmdir command, it will also delete all the files contained in the real target directory.

Ref: MKLINK


About the UNC, Any custom "HyperOverride directory" must be placed inside the HyperOverride directory.

Example: C:\Program Files\Baldur's Gate\HyperOverride\MySpecialOverride

with such shortcut to launch the game: HOLoad -ho:MySpecialOverride

HOLoad only accepts the final directory and automatically prefixes it with "C:\Program Files\Baldur's Gate\HyperOverride\" (or wherever your BG is installed) to find the full path.
HOLoad does not accept a full path. So you cannot specify a full path whatever the form including UNC.

Note, that if you are really about splitting stuff on various HD, and using HyperOverride you can still use a Direction Junction for the HyperOverride folders as well if needed. I don't know why would someone resort to such configuration but since you are interested, just pointing it out

Edited by Elys, 02 March 2012 - 01:34 PM.